FLuorescence EXplorer simulation

The FLuorescence EXplorer (FLEX) mission is devoted to monitor the photosynthetic activity of the terrestrial vegetation layer¹⁾. The natural fluorescence signal is weak compared to the reflected solar radiation. However, by measuring at wavelengths where the solar spectrum is attenuated, for example the O₂-A and B bands, information about natural fluorescence may be retrieved ²⁾. The top of the atmosphere (TOA) radiance in the O₂-A and B bands is influenced by the fluorescence magnitude, surface pressure, aerosol optical depth, aerosol layer height and aerosol type. Radiative transfer models may be used to quantify these effects.

In this example we show how uvspec may be used to simulate the TOA radiance in the O₂-A and B bands representative for the FLEX mission. It is also shown how rotational Raman scattering may be included in the simulation.

The key instrument for the FLEX mission is the FLuORescence Imaging Spectrometer (FLORIS). It is planned to measure at 0.3~nm spectral resolution. Thus radiative transfer simulations should be carried out at higher spectral resolution and convolved with an appropriate spectral response function. This requires a solar spectrum with high spectral resolution. Here we use a spectrum with 0.01 nm resolution³⁾ The solar spectrum must have the same units as the fluorescence spectrum. We use units of photons/nm/s/m² in order to be able to include rotational Raman scattering. The following uvspec option specifies the solar source:

source solar ./UVSPEC_FLUORESCENCE_kurucz_640.0_810.0.dat_vac_0.01_0.01

The wavelengths to be covered are set as follows:

wavelength 750 770 #  O2-A band

Change this to

wavelength 677 697 #  O2-B band

for the O₂-B band.

High resolution absorption cross sections of the appropriate gases are needed in the spectral region of interest. Here we use the ARTS-model to calculate high-resolution absorption optical depth profiles including O₂, H₂O, CO₂, O₃, CO and CH₄. It is noted that most of the absorption line structures are due to H₂O except for the O₂-A and B bands. The arts input file looks as follow.

#DEFINITIONS:  -*-sh-*-
Arts2 {
INCLUDE "general"
INCLUDE "continua"

# Create some variables:
NumericCreate(fmin)
NumericCreate(fmax)
NumericCreate(wvl_min)
NumericCreate(wvl_max)
VectorCreate(wvl_grid)

# Set minimum and maximum wavelength
NumericSet(wvl_min, 0.6400e-6)  # 650 nm
NumericSet(wvl_max, 0.8100e-6)  # 810 nm
VectorNLinSpace( wvl_grid, 17001,  wvl_max, wvl_min )

# Convert to Hz, maximum wavelength = minimum frequency:
FrequencyFromWavelength(f_grid, wvl_grid) 
FrequencyFromWavelength(fmax, wvl_min) 
FrequencyFromWavelength(fmin, wvl_max)  

# Read HITRAN data
abs_linesReadFromHitran2004( abs_lines,
	       "/home/arve/Projects/data/HITRAN/HITRAN04.par",
	        fmin,
              fmax)

# Set species to be considered in line-by-line calculation
SpeciesSet(abs_species,[ 
   "H2O, H2O-SelfContCKDMT100, H2O-ForeignContCKDMT100",
   "CO2, CO2-CKDMT100",
   "O3",
   "CO",
   "CH4",
   "O2, O2-CIAfunCKDMT100"
  ])

# This separates the lines into the different tag groups and creates
# the workspace variable `abs_lines_per_species':
abs_lines_per_speciesCreateFromLines

# Atmospheric profiles (there is several data in the
# arts-xml-data/atmosphere directory, fascod includes the standard
# atmospheres which we also have in libRadtran (altitude only up to
# 95 km !!). When you want to use the molecular_tau_file from arts,
# the atmosphere_file for uvspec must correspond to the ARTS
# atmosphere files which are defined here!!) 
AtmRawRead( t_field_raw, z_field_raw, vmr_field_raw, abs_species, 
  "/home/arve/arts/arts-xml-data-1.1.31/atmosphere/fascod/midlatitude-summer" )

# Extract pressure grid from atmosphere files (this is the vertical
# coordinate for all calculations, can be specified as you like)
p_gridFromAtmRaw(p_grid, z_field_raw)

# Now interpolate all the raw atmospheric input onto the pressure 
# grid and create the atmospheric variables `t_field', `z_field', `vmr_field'
AtmFieldsCalc

# Initialize the input variables of abs_coefCalc from the Atm fields:
AbsInputFromAtmFields
abs_h2oSet

# Non-linear species
SpeciesSet( abs_nls,[ ])

# Perturbation if lookup-table should be created that can be used for a wide range of atmospheric conditions
VectorSet( abs_t_pert, [] )
VectorSet( abs_nls_pert, [] )

# Calculate absorption field:
IndexSet(f_index, -1) # calculate all frequencies
abs_fieldCalc

# Write molecular_tau_file for libRadtran
WriteMolTau ( f_grid, z_field, abs_field, atmosphere_dim, "UVSPEC_FLUORESCENCE_arts-640-810.nc" )
}

The molecular optical depth file covers both the O₂-A and B bands. It is input to uvspec with the following line:

mol_tau_file abs ./UVSPEC_FLUORESCENCE_arts-640-810.nc

The atmosphere density file must contain the same information for both arts and uvspec. That is, the same molecular gas densities at the same vertical resolution. Arts have several atmospheric models in the arts-xml-data/atmosphere directory. Here we use the mid-latitude summer atmosphere model.

atmosphere_file ./afglms_95.dat

For the surface the surface albedo and the flourescence must be specified. We use spectral data from the ESA-FLUSS project⁴⁾ The following parameters were used: Chlorophyll a and b 40; Stoichiometry 1; Fluorescence 0.02; Relative azimuth angle 40; Viewing zenith angle 41.4; Leaf are index 3; Soil-type code 2; Solar zenith angle 30.

fluorescence_file ./UVSPEC_FLUORESCENCE.FLU_ph
albedo_file ./UVSPEC_FLUORESCENCE.TOC

The solar zenith angle must be specified. This should equal the solar zenith angle used to calculate the fluorescence and surface albedo spectra.

sza 30.0

Furthermore we assume the instrument is nadir viewing and of course is at TOA.

umu 1     # Looking down
zout toa  # top of atmosphere